trAvis - MANAGER

Edit File: FindPostgreSQL.cmake

# - Find the PostgreSQL installation.
# In Windows, we make the assumption that, if the PostgreSQL files are installed, the default directory
# will be C:\Program Files\PostgreSQL.
#
# This module defines
#  PostgreSQL_LIBRARIES - the PostgreSQL libraries needed for linking
#  PostgreSQL_INCLUDE_DIRS - the directories of the PostgreSQL headers
#  PostgreSQL_VERSION_STRING - the version of PostgreSQL found (since CMake 2.8.8)

#=============================================================================
# Copyright 2004-2009 Kitware, Inc.
#
# Distributed under the OSI-approved BSD License (the "License");
# see accompanying file Copyright.txt for details.
#
# This software is distributed WITHOUT ANY WARRANTY; without even the
# implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
# See the License for more information.
#=============================================================================
# (To distribute this file outside of CMake, substitute the full
#  License text for the above reference.)

# ----------------------------------------------------------------------------
# History:
# This module is derived from the module originally found in the VTK source tree.
#
# ----------------------------------------------------------------------------
# Note:
# PostgreSQL_ADDITIONAL_VERSIONS is a variable that can be used to set the
# version mumber of the implementation of PostgreSQL.
# In Windows the default installation of PostgreSQL uses that as part of the path.
# E.g C:\Program Files\PostgreSQL\8.4.
# Currently, the following version numbers are known to this module:
# "9.1" "9.0" "8.4" "8.3" "8.2" "8.1" "8.0"
#
# To use this variable just do something like this:
# set(PostgreSQL_ADDITIONAL_VERSIONS "9.2" "8.4.4")
# before calling find_package(PostgreSQL) in your CMakeLists.txt file.
# This will mean that the versions you set here will be found first in the order
# specified before the default ones are searched.
#
# ----------------------------------------------------------------------------
# You may need to manually set:
#  PostgreSQL_INCLUDE_DIR  - the path to where the PostgreSQL include files are.
#  PostgreSQL_LIBRARY_DIR  - The path to where the PostgreSQL library files are.
# If FindPostgreSQL.cmake cannot find the include files or the library files.
#
# ----------------------------------------------------------------------------
# The following variables are set if PostgreSQL is found:
#  PostgreSQL_FOUND         - Set to true when PostgreSQL is found.
#  PostgreSQL_INCLUDE_DIRS  - Include directories for PostgreSQL
#  PostgreSQL_LIBRARY_DIRS  - Link directories for PostgreSQL libraries
#  PostgreSQL_LIBRARIES     - The PostgreSQL libraries.
#
# ----------------------------------------------------------------------------
# If you have installed PostgreSQL in a non-standard location.
# (Please note that in the following comments, it is assumed that <Your Path>
# points to the root directory of the include directory of PostgreSQL.)
# Then you have three options.
# 1) After CMake runs, set PostgreSQL_INCLUDE_DIR to <Your Path>/include and
#    PostgreSQL_LIBRARY_DIR to wherever the library pq (or libpq in windows) is
# 2) Use CMAKE_INCLUDE_PATH to set a path to <Your Path>/PostgreSQL<-version>. This will allow find_path()
#    to locate PostgreSQL_INCLUDE_DIR by utilizing the PATH_SUFFIXES option. e.g. In your CMakeLists.txt file
#    set(CMAKE_INCLUDE_PATH ${CMAKE_INCLUDE_PATH} "<Your Path>/include")
# 3) Set an environment variable called ${PostgreSQL_ROOT} that points to the root of where you have
#    installed PostgreSQL, e.g. <Your Path>.
#
# ----------------------------------------------------------------------------

set(PostgreSQL_INCLUDE_PATH_DESCRIPTION "top-level directory containing the PostgreSQL include directories. E.g /usr/local/include/PostgreSQL/8.4 or C:/Program Files/PostgreSQL/8.4/include")
set(PostgreSQL_INCLUDE_DIR_MESSAGE "Set the PostgreSQL_INCLUDE_DIR cmake cache entry to the ${PostgreSQL_INCLUDE_PATH_DESCRIPTION}")
set(PostgreSQL_LIBRARY_PATH_DESCRIPTION "top-level directory containing the PostgreSQL libraries.")
set(PostgreSQL_LIBRARY_DIR_MESSAGE "Set the PostgreSQL_LIBRARY_DIR cmake cache entry to the ${PostgreSQL_LIBRARY_PATH_DESCRIPTION}")
set(PostgreSQL_ROOT_DIR_MESSAGE "Set the PostgreSQL_ROOT system variable to where PostgreSQL is found on the machine E.g C:/Program Files/PostgreSQL/8.4")

set(PostgreSQL_KNOWN_VERSIONS ${PostgreSQL_ADDITIONAL_VERSIONS}
    "9.1" "9.0" "8.4" "8.3" "8.2" "8.1" "8.0")

# Define additional search paths for root directories.
if ( WIN32 )
  foreach (suffix ${PostgreSQL_KNOWN_VERSIONS} )
    set(PostgreSQL_ADDITIONAL_SEARCH_PATHS ${PostgreSQL_ADDITIONAL_SEARCH_PATHS} "C:/Program Files/PostgreSQL/${suffix}" )
  endforeach()
endif()
set( PostgreSQL_ROOT_DIRECTORIES
   ENV PostgreSQL_ROOT
   ${PostgreSQL_ROOT}
   ${PostgreSQL_ADDITIONAL_SEARCH_PATHS}
)

#
# Look for an installation.
#
find_path(PostgreSQL_CONFIG_DIR
  NAMES pg_config
  PATHS
   # Look in other places.
   ${PostgreSQL_ROOT_DIRECTORIES}
  PATH_SUFFIXES
    ""
    bin
  # Help the user find it if we cannot.
  DOC "The ${PostgreSQL_ROOT_DIR_MESSAGE}"
)

macro (fail_if)
  if (${ARGV})
    message (WARNING "Couldn't determine PostgreSQL configuration.")
    unset (PostgreSQL_CONFIG_DIR)
    break ()
  endif ()
endmacro ()

macro (run_pg_config arg var)
  execute_process(COMMAND ${PostgreSQL_CONFIG_DIR}/pg_config ${arg}
                  RESULT_VARIABLE pgsql_config_result
                  OUTPUT_VARIABLE ${var}
                  OUTPUT_STRIP_TRAILING_WHITESPACE)

fail_if (NOT ${pgsql_config_result} EQUAL 0 OR NOT ${var})
endmacro ()

foreach (once only)
  fail_if (NOT PostgreSQL_CONFIG_DIR)

run_pg_config (--version PostgreSQL_VERSION_STRING)
  string (REGEX REPLACE "^PostgreSQL (.*)$" "\\1"
          PostgreSQL_VERSION_STRING "${PostgreSQL_VERSION_STRING}")
  fail_if (NOT PostgreSQL_VERSION_STRING)

run_pg_config (--includedir PostgreSQL_INCLUDE_DIR)
  fail_if (NOT EXISTS "${PostgreSQL_INCLUDE_DIR}/libpq-fe.h")

find_path(PostgreSQL_TYPE_INCLUDE_DIR
    NAMES catalog/pg_type.h
    PATHS ${PostgreSQL_INCLUDE_DIR}
    PATH_SUFFIXES
      pgsql/server
      postgresql/server
      include/server
    # Help the user find it if we cannot.
    DOC "The ${PostgreSQL_INCLUDE_DIR_MESSAGE}"
  )
  fail_if (NOT PostgreSQL_TYPE_INCLUDE_DIR)

set (PostgreSQL_INCLUDE_DIRS
       ${PostgreSQL_INCLUDE_DIR} ${PostgreSQL_TYPE_INCLUDE_DIR})

run_pg_config (--libdir PostgreSQL_LIBRARY_DIRS)

# The PostgreSQL library.
  set (PostgreSQL_LIBRARY_TO_FIND pq)
  # Setting some more prefixes for the library
  set (PostgreSQL_LIB_PREFIX "")
  if (WIN32)
    set (PostgreSQL_LIB_PREFIX ${PostgreSQL_LIB_PREFIX} "lib")
    set (PostgreSQL_LIBRARY_TO_FIND ${PostgreSQL_LIB_PREFIX}${PostgreSQL_LIBRARY_TO_FIND})
  endif()

find_library (PostgreSQL_LIBRARY
    NAMES ${PostgreSQL_LIBRARY_TO_FIND}
    PATHS ${PostgreSQL_LIBRARY_DIRS}
    PATH_SUFFIXES lib
  )
  fail_if (NOT PostgreSQL_LIBRARY)
  set (PostgreSQL_LIBRARIES ${PostgreSQL_LIBRARY_TO_FIND})

endforeach()

# Did we find anything?
include (FindPackageHandleStandardArgs)
find_package_handle_standard_args (PostgreSQL
  REQUIRED_VARS
    PostgreSQL_LIBRARY_DIRS
    PostgreSQL_CONFIG_DIR
    PostgreSQL_INCLUDE_DIRS
    PostgreSQL_LIBRARIES
  VERSION_VAR
    PostgreSQL_VERSION_STRING
)
set (PostgreSQL_FOUND ${POSTGRESQL_FOUND})

# Now try to get the include and library path.
if (PostgreSQL_FOUND)
  message (STATUS "PostgreSQL include dirs: ${PostgreSQL_INCLUDE_DIRS}")
  message (STATUS "PostgreSQL library dirs: ${PostgreSQL_LIBRARY_DIRS}")
  message (STATUS "PostgreSQL libraries:    ${PostgreSQL_LIBRARIES}")
endif()